文字列のコードページを変換する

Imports System
Imports System.Text

Module Module1

    Sub Main()

        Dim source(), encoded() As Byte

        ' 元のエンコーディングはUnicode
        Dim sourceEncoding As Encoding = Encoding.Unicode

        ' 変換するエンコーディング
        Dim encodings() As Encoding = New Encoding() { _
                                Encoding.GetEncoding("iso-2022-jp"), _
                                Encoding.GetEncoding("shift_jis"), _
                                Encoding.GetEncoding("euc-jp"), _
                                Encoding.GetEncoding("utf-8"), _
                                Encoding.GetEncoding("unicodefffe")}

        ' 文字列をバイト配列に変換
        source = sourceEncoding.GetBytes("ABCあいうアイウ漢字")

        ' 各エンコーディングで変換
        Dim enc As Encoding

        For Each enc In encodings

            ' エンコーディング名を表示
            Console.WriteLine("Encoding: {0}", enc.EncodingName)

            ' 指定されたエンコーディングで変換
            encoded = Encoding.Convert(sourceEncoding, enc, source)

            ' 変換されたバイト配列を文字列として表示する
            Console.WriteLine("{0}, 計{1}バイト", enc.GetString(encoded), encoded.Length)

            ' バイト配列をダンプする
            DumpByteArray(encoded)

            ' 単なる改行
            Console.WriteLine()

        Next

    End Sub

    Sub DumpByteArray(ByVal arr() As Byte)

        Dim pos As Integer = 0
        Dim len As Integer = arr.Length

        Do

            Dim i As Integer
            Dim c As Integer

            If len <= pos + &H10 Then

                c = len - pos

            Else

                c = &H10

            End If

            For i = 0 To c - 1

                Console.Write("{0:X2} ", arr(pos + i))

            Next

            Console.WriteLine()

            pos += &H10

        Loop Until len <= pos

    End Sub

End Module

using System;
using System.Text;

namespace TextCodec
{
    class Class1
    {
        [STAThread]
        static void Main(string[] args)
        {
            byte[] source, encoded;

            // 元のエンコーディングはUnicode
            Encoding sourceEncoding = Encoding.Unicode;

            // 変換するエンコーディング
            Encoding[] encodings = new Encoding[] {
                                        Encoding.GetEncoding("iso-2022-jp"),   // JIS, 50222
                                        Encoding.GetEncoding("shift_jis"),     // シフトJIS, 932
                                        Encoding.GetEncoding("euc-jp"),        // 日本語EUC, 15932
                                        Encoding.GetEncoding("utf-8"),         // UTF-8, 65001
                                        Encoding.GetEncoding("unicodefffe") }; // Unicode(Big-Endian). 1201

            // 文字列をバイト配列に変換
            source = sourceEncoding.GetBytes( "ABCあいうアイウ漢字" );

            // 各エンコーディングで変換
            foreach ( Encoding encoding in encodings )
            {
                // エンコーディング名を表示
                Console.WriteLine( "Encoding: {0}", encoding.EncodingName );

                // 指定されたエンコーディングで変換
                encoded = Encoding.Convert( sourceEncoding, encoding, source );

                // 変換されたバイト配列を文字列として表示する
                Console.WriteLine( "{0}, 計{1}バイト", encoding.GetString( encoded ), encoded.Length );

                // バイト配列をダンプする
                DumpByteArray( encoded );

                // 単なる改行
                Console.WriteLine();
            }
        }

        // バイト配列をダンプする
        static void DumpByteArray( byte[] arr )
        {
            int pos = 0;
            int len = arr.Length;

            do
            {
                int i;
                int c;

                if ( len <= pos + 0x10 ) 
                {
                    c = len - pos;
                }
                else
                {
                    c = 0x10;
                }

                for ( i = 0; i <= c - 1; i += 1 )
                {
                    Console.Write( "{0:X2} ", arr[pos + i]);
                }

                Console.WriteLine();

                pos += 0x10;

            } while ( !( ( len <= pos ) ) );
        }
    }
}