System.Globalizationでグローバル指向プログラミング

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        ' 現在のカルチャ
        Dim culture As CultureInfo = CultureInfo.CurrentCulture

        ' カルチャ名
        Console.WriteLine(culture.Name)
        Console.WriteLine(culture.DisplayName)
        Console.WriteLine(culture.EnglishName)
        Console.WriteLine(culture.NativeName)
        Console.WriteLine(culture.ThreeLetterISOLanguageName)

        ' カルチャ情報
        Console.WriteLine(culture.Calendar)
        Console.WriteLine(culture.DateTimeFormat.LongDatePattern)
        Console.WriteLine(culture.DateTimeFormat.LongTimePattern)
        Console.WriteLine(culture.DateTimeFormat.ShortDatePattern)
        Console.WriteLine(culture.DateTimeFormat.ShortTimePattern)
        Console.WriteLine(culture.TextInfo.ANSICodePage)
        Console.WriteLine(culture.NumberFormat.CurrencySymbol)

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        ' 他のカルチャ情報 (英語 - 米国)
        Dim culture As New CultureInfo("en-US")

        ' カルチャ名
        Console.WriteLine("{0}, {1}", culture.Name, culture.NativeName)

        ' カルチャ情報
        Console.WriteLine(culture.Calendar)
        Console.WriteLine(culture.DateTimeFormat.LongDatePattern)
        Console.WriteLine(culture.DateTimeFormat.LongTimePattern)
        Console.WriteLine(culture.DateTimeFormat.ShortDatePattern)
        Console.WriteLine(culture.DateTimeFormat.ShortTimePattern)
        Console.WriteLine(culture.TextInfo.ANSICodePage)
        Console.WriteLine(culture.NumberFormat.CurrencySymbol)

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        Dim cultures() As CultureInfo = CultureInfo.GetCultures(CultureTypes.AllCultures)
        Dim culture As CultureInfo

        Debug.WriteLine("Cultures: " + cultures.Length.ToString())

        For Each culture In cultures

            Debug.WriteLine(culture.Name + ", " + culture.NativeName)

        Next

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        Dim currency As Decimal = 123456.78D

        ' 現在のカルチャ(日本)
        OutputCurrency(currency, CultureInfo.CurrentCulture)

        ' アメリカ
        OutputCurrency(currency, New CultureInfo("en-US"))

        ' カナダ
        OutputCurrency(currency, New CultureInfo("en-CA"))

        ' イギリス
        OutputCurrency(currency, New CultureInfo("en-GB"))

        ' フランス
        OutputCurrency(currency, New CultureInfo("fr-FR"))

        ' ドイツ
        OutputCurrency(currency, New CultureInfo("de-DE"))

        ' イタリア
        OutputCurrency(currency, New CultureInfo("it-IT"))

        ' ロシア
        OutputCurrency(currency, New CultureInfo("ru-RU"))

    End Sub

    Sub OutputCurrency(ByVal currency As Decimal, ByVal culture As CultureInfo)

        Debug.WriteLine(culture.DisplayName + ": " + currency.ToString("C", culture.NumberFormat))

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        Dim intValue As Integer = 12345678
        Dim realValue As Double = 12345.678

        ' 現在のカルチャ(日本)
        OutputValue(intValue, realValue, CultureInfo.CurrentCulture)

        ' アメリカ
        OutputValue(intValue, realValue, New CultureInfo("en-US"))

        ' カナダ
        OutputValue(intValue, realValue, New CultureInfo("en-CA"))

        ' イギリス
        OutputValue(intValue, realValue, New CultureInfo("en-GB"))

        ' フランス
        OutputValue(intValue, realValue, New CultureInfo("fr-FR"))

        ' ドイツ
        OutputValue(intValue, realValue, New CultureInfo("de-DE"))

        ' イタリア
        OutputValue(intValue, realValue, New CultureInfo("it-IT"))

        ' ロシア
        OutputValue(intValue, realValue, New CultureInfo("ru-RU"))

    End Sub

    Sub OutputValue(ByVal i As Integer, ByVal r As Double, ByVal culture As CultureInfo)

        Debug.WriteLine(culture.DisplayName + ": " + _
         i.ToString("D", culture.NumberFormat) + _
         "  " + r.ToString("E", culture.NumberFormat) + _
         "  " + r.ToString("F", culture.NumberFormat) + _
         "  " + r.ToString("G", culture.NumberFormat) + _
         "  " + r.ToString("N", culture.NumberFormat))

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        Dim dtmNow As DateTime = DateTime.Now

        ' 現在のカルチャ(日本)
        OutputDateTime(dtmNow, CultureInfo.CurrentCulture)

        ' アメリカ
        OutputDateTime(dtmNow, New CultureInfo("en-US"))

        ' カナダ
        OutputDateTime(dtmNow, New CultureInfo("en-CA"))

        ' イギリス
        OutputDateTime(dtmNow, New CultureInfo("en-GB"))

        ' フランス
        OutputDateTime(dtmNow, New CultureInfo("fr-FR"))

        ' ドイツ
        OutputDateTime(dtmNow, New CultureInfo("de-DE"))

        ' イタリア
        OutputDateTime(dtmNow, New CultureInfo("it-IT"))

        ' ロシア
        OutputDateTime(dtmNow, New CultureInfo("ru-RU"))

        ' 韓国
        OutputDateTime(dtmNow, New CultureInfo("ko-KR"))

        ' 中国
        OutputDateTime(dtmNow, New CultureInfo("zh-CN"))

    End Sub

    Sub OutputDateTime(ByVal dtm As DateTime, ByVal culture As CultureInfo)

        Debug.WriteLine(culture.DisplayName + ": " + dtm.ToString(culture.DateTimeFormat))

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        ' カルチャのインスタンスを生成
        Dim culture As New CultureInfo("ja-JP")

        ' カルチャから日時のフォーマット情報を取得
        Dim format As DateTimeFormatInfo = culture.DateTimeFormat

        ' 現在のカレンダ
        Debug.WriteLine(format.Calendar.ToString())

        ' 曜日名を列挙
        EnumerateDayNames(format)

        ' 月の名前を列挙
        EnumerateMonthNames(format)

        ' 時代(年号)を列挙
        EnumerateEras(format)



        ' 暦を和暦に設定
        format.Calendar = New JapaneseCalendar()

        ' 現在のカレンダ
        Debug.WriteLine(format.Calendar.ToString())

        ' 時代(年号)を列挙
        EnumerateEras(format)

    End Sub

    ' 曜日を表す文字列を列挙するメソッド
    Sub EnumerateDayNames(ByVal format As DateTimeFormatInfo)

        Dim dayName As String

        For Each dayName In format.DayNames

            Debug.Write(dayName + ", ")

        Next

        Debug.WriteLine("")

    End Sub

    ' 月を表す文字列を列挙するメソッド
    Sub EnumerateMonthNames(ByVal format As DateTimeFormatInfo)

        Dim monthName As String

        For Each monthName In format.MonthNames

            Debug.Write(monthName + ", ")

        Next

        Debug.WriteLine("")

    End Sub

    ' 時代(年号)を列挙するメソッド
    Sub EnumerateEras(ByVal format As DateTimeFormatInfo)

        Dim era As Integer

        For Each era In format.Calendar.Eras

            Debug.WriteLine(era.ToString() + " : " + format.GetEraName(era))

        Next

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        ' カルチャのインスタンスを生成
        Dim cultures() As CultureInfo = { _
         New CultureInfo("ja-JP"), _
         New CultureInfo("en-US"), _
         New CultureInfo("de-DE"), _
         New CultureInfo("fr-FR"), _
         New CultureInfo("ru-RU"), _
         New CultureInfo("ko-KR"), _
         New CultureInfo("zh-CN")}

        Dim culture As CultureInfo

        Dim format As DateTimeFormatInfo

        For Each culture In cultures

            ' カルチャから日時のフォーマット情報を取得
            format = culture.DateTimeFormat

            Debug.WriteLine(culture.ToString())

            ' 曜日名を列挙
            EnumerateDayNames(format)

            ' 月の名前を列挙
            EnumerateMonthNames(format)

        Next

    End Sub

    ' 曜日を表す文字列を列挙するメソッド
    Sub EnumerateDayNames(ByVal format As DateTimeFormatInfo)

        ' 省略

    End Sub

    ' 月を表す文字列を列挙するメソッド
    Sub EnumerateMonthNames(ByVal format As DateTimeFormatInfo)

        ' 省略

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        Dim japanese As New JapaneseCalendar()

        Dim gregorian As New GregorianCalendar()

        Dim gregDateTime As DateTime

        ' 和暦の平成15年2月7日をグレゴリオ暦(西暦)に直す
        gregDateTime = japanese.ToDateTime(15, 2, 7, 0, 0, 0, 0, japanese.CurrentEra)

        Console.WriteLine(gregDateTime)

        ' 西暦でその年を取得する
        Console.WriteLine("Gregorian: {0}", gregorian.GetYear(gregDateTime))

        ' 和暦でその年を取得する
        Console.WriteLine("Japanese: {0}", japanese.GetYear(gregDateTime))

    End Sub

End Module

Imports System
Imports System.Globalization

Module Globalization

    Sub Main()

        ' システムの暦での2001年1月1日
        Dim dtm As DateTime = New DateTime(2001, 1, 1)

        ' 和暦
        Dim japanese As New JapaneseCalendar()

        ' ヘブライ暦
        Dim hebrew As New HebrewCalendar()

        ' 回教暦
        Dim hijri As New HijriCalendar()

        ' 西暦
        Dim gregorian As New GregorianCalendar()


        ' システムの暦を表示
        Console.WriteLine("Using {0}", CultureInfo.CurrentCulture.Calendar)

        ' 日付を表示
        Console.WriteLine(dtm)

        ' 和暦での一年後、十年後
        Console.WriteLine("Japanese:  {0}, {1}", japanese.AddYears(dtm, 1), japanese.AddYears(dtm, 10))

        ' ヘブライ暦での一年後、十年後
        Console.WriteLine("Hebrew:    {0}, {1}", hebrew.AddYears(dtm, 1), hebrew.AddYears(dtm, 10))

        ' 回教暦での一年後、十年後
        Console.WriteLine("Hijri:     {0}, {1}", hijri.AddYears(dtm, 1), hijri.AddYears(dtm, 10))

        ' 西暦での一年後、十年後
        Console.WriteLine("Gregorian: {0}, {1}", gregorian.AddYears(dtm, 1), gregorian.AddYears(dtm, 10))

    End Sub

End Module

Option Strict On

Imports System
Imports System.Globalization
Imports System.Threading

Module Globalization

    Sub Main()

        Console.WriteLine("現在のカルチャ: {0}", CultureInfo.CurrentCulture.NativeName)

        ' 通貨の表示
        Console.WriteLine("{0:C}", 123456.789)

        ' 日時の表示
        Console.WriteLine("{0}", DateTime.Now)


        ' 現在のスレッドのカルチャを変更
        Thread.CurrentThread.CurrentCulture = New CultureInfo("en-US")


        Console.WriteLine("現在のカルチャ: {0}", CultureInfo.CurrentCulture.NativeName)

        ' 通貨の表示
        Console.WriteLine("{0:C}", 123456.789)

        ' 日時の表示
        Console.WriteLine("{0}", DateTime.Now)

    End Sub

End Module

Imports System
Imports System.Globalization
Imports System.Threading

Module Globalization

    Sub Main()

        ' 日時の表示
        Console.WriteLine("{0}", DateTime.Now)

        ' 新しいカルチャのインスタンスを生成
        Dim culture As New CultureInfo("ja-JP")

        ' カルチャに新しく和暦を指定 
        culture.DateTimeFormat.Calendar = New JapaneseCalendar()

        ' 現在のスレッドのカルチャを変更
        Thread.CurrentThread.CurrentCulture = culture

        ' 日時の表示
        Console.WriteLine("{0}", DateTime.Now)

    End Sub

End Module