アセンブリへのリソースの埋め込みと読み込み

Option Strict On

Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows フォーム デザイナで生成されたコード "
#End Region

    ' アイコン
    Dim ico As Drawing.Icon

    ' 画像
    Dim img As Drawing.Image

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        ' 現在実行中のアセンブリを取得
        Dim assm As Reflection.Assembly = Reflection.Assembly.GetExecutingAssembly()

        ' リソースを読み込むためのストリームを宣言
        Dim stream As IO.Stream



        ' アイコンのリソースのストリームを取得
        stream = assm.GetManifestResourceStream("ResourceAndMultimedia.ApplicationIcon.ico")

        ' ストリームを引数として取るコンストラクタを使用
        ico = New Drawing.Icon(stream)

        ' ストリームをクローズ
        stream.Close()

        ' 取得したアイコンをフォームのアイコンとして指定
        Me.Icon = ico



        ' イメージのリソースのストリームを取得
        stream = assm.GetManifestResourceStream("ResourceAndMultimedia.Sample.jpg")

        ' ストリームを引数として取るコンストラクタを使用
        img = New Drawing.Bitmap(stream)

        ' ストリームをクローズ
        stream.Close()



        ' テキストのリソースのストリームを取得
        stream = assm.GetManifestResourceStream("ResourceAndMultimedia.Sample.txt")

        ' リソースのストリームからStreamReaderオブジェクトを作成
        Dim reader As New IO.StreamReader(stream, System.Text.Encoding.GetEncoding(932))

        TextBox1.Text = ""

        ' 一行ずつ読み込み
        While (reader.Peek <> -1)

            TextBox1.Text += reader.ReadLine() + vbNewLine

        End While

        ' ストリームをクローズ
        reader.Close()

    End Sub


    Private Sub Form1_Paint(ByVal sender As System.Object, _
                 ByVal e As System.Windows.Forms.PaintEventArgs) Handles MyBase.Paint

        e.Graphics.Clear(Control.DefaultBackColor)

        ' フォーム上に画像を描画
        e.Graphics.DrawImage(img, 0, 0)

    End Sub

End Class

Option Strict On

Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows フォーム デザイナで生成されたコード "
#End Region

    ' バッファ(バイト配列)から音を鳴らすためのPlaySound関数 (API関数)
    <Runtime.InteropServices.DllImport("winmm.dll", EntryPoint:="PlaySound")> _
    Private Shared Function PlaySoundFromMemory( _
       <Runtime.InteropServices.MarshalAs(Runtime.InteropServices.UnmanagedType.LPArray)> ByVal lpBuffer As Byte(), _
       ByVal hModule As Integer, _
       ByVal dwFlags As Integer) _
       As Integer
    End Function

    ' PlaySound関数で再生方法を指定する定数
    Private Const SND_ASYNC As Integer = &H1    ' 非同期再生
    Private Const SND_MEMORY As Integer = &H4    ' バッファからの再生

    ' バッファとしてのバイト配列
    Dim soundBuffer() As Byte

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        ' 現在実行中のアセンブリを取得
        Dim assm As Reflection.Assembly = Reflection.Assembly.GetExecutingAssembly()

        ' リソースのストリームを取得
        Dim stream As IO.Stream = assm.GetManifestResourceStream("ResourceAndMultimedia.Sample.wav")

        ' 取得できたストリームを元にバイナリ形式で読み込むためのBinaryReaderオブジェクトを作成
        Dim reader As New IO.BinaryReader(stream)

        ' バッファにリソースの内容を読み込み
        soundBuffer = reader.ReadBytes(CInt(reader.BaseStream.Length))

        ' ストリームをクローズ
        reader.Close()

    End Sub

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        ' バッファを再生
        PlaySoundFromMemory(soundBuffer, Nothing, SND_ASYNC Or SND_MEMORY)

    End Sub

End Class

BOOL PlaySound(
    LPCSTR pszSound,  // 再生対象のサウンド
    HMODULE hmod,     // インスタンスハンドル
    DWORD fdwSound    // 再生フラグ
);