オブジェクトのXMLシリアル化

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        ' XMLシリアル化の対象となるインスタンスを作成
        Dim aibon As New ClassForSerialization("加護亜依", 15, "AB")

        ' XmlSerializer インスタンスを作成
        Dim serializer As New XmlSerializer(aibon.GetType)

        ' XMLファイルを書き出すための StreamWriter インスタンスを作成
        Dim writer As New StreamWriter("E:\Serialization_00.xml", False, Encoding.UTF8)

        ' XMLシリアル化
        serializer.Serialize(writer, aibon)

        ' ファイルをクローズ
        writer.Close()

        Return 0

    End Function

End Module

' シリアル化の対象となるクラス
<Serializable()> _
Public Class ClassForSerialization

    ' シリアル化の対象となるメンバ
    Public Name As String
    Public Age As Integer
    Public BloodType As String

    ' XMLシリアル化には既定のコンストラクタが必要
    Public Sub New()
    End Sub

    ' コンストラクタ
    Public Sub New(ByVal Name As String, ByVal Age As Integer, ByVal BloodType As String)

        Me.Name = Name
        Me.Age = Age
        Me.BloodType = BloodType

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        ' オブジェクト変数を宣言
        Dim aibon As ClassForSerialization

        ' XmlSerializer インスタンスを作成
        Dim serializer As New XmlSerializer(GetType(ClassForSerialization))

        ' XMLファイルを読み出すための StreamReader インスタンスを作成
        Dim reader As New StreamReader("E:\Serialization_00.xml")

        ' XMLシリアル化
        aibon = serializer.Deserialize(reader)

        ' ファイルをクローズ
        reader.Close()

        ' インスタンスのフィールド値を出力
        Console.WriteLine("名前: {0} ({1}歳, {2}型)", aibon.Name, aibon.Age, aibon.BloodType)

        Return 0

    End Function

End Module

' シリアル化の対象となるクラス
<Serializable()> _
Public Class ClassForSerialization

    ' シリアル化の対象となるメンバ
    Public Name As String
    Public Age As Integer
    Public BloodType As String

    ' XMLシリアル化には既定のコンストラクタが必要
    Public Sub New()
    End Sub

    ' コンストラクタ
    Public Sub New(ByVal Name As String, ByVal Age As Integer, ByVal BloodType As String)

        Me.Name = Name
        Me.Age = Age
        Me.BloodType = BloodType

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        ' XMLシリアル化の対象となるインスタンスを作成
        Dim aibon As New ClassForSerialization("加護亜依", 15, "AB", New DateTime(1988, 2, 7), "奈良県")

        ' XmlSerializer インスタンスを作成
        Dim serializer As New XmlSerializer(aibon.GetType)

        ' XMLファイルを書き出すための StreamWriter インスタンスを作成
        Dim writer As New StreamWriter("E:\Serialization_01.xml", False, Encoding.UTF8)

        ' XMLシリアル化
        serializer.Serialize(writer, aibon)

        ' ファイルをクローズ
        writer.Close()

        Return 0

    End Function

End Module

' シリアル化の対象となるクラス
<Serializable()> _
Public Class ClassForSerialization

    ' パブリックフィールド
    Public Name As String
    Public Age As Integer

    ' プロテクティッドフィールド
    Protected m_BloodType As String

    ' プライベートフィールド
    Private m_BirthDate As DateTime
    Private m_BirthPlace As String

    ' パブリックプロパティ
    Public Property BirthDate() As DateTime
        Get
            Return m_BirthDate
        End Get
        Set(ByVal Value As DateTime)
            m_BirthDate = Value
        End Set
    End Property

    ' プライベートプロパティ
    Private Property BirthPlace() As String
        Get
            Return m_BirthPlace
        End Get
        Set(ByVal Value As String)
            m_birthplace = Value
        End Set
    End Property

    ' XMLシリアル化には既定のコンストラクタが必要
    Public Sub New()
    End Sub

    ' コンストラクタ
    Public Sub New(ByVal Name As String, ByVal Age As Integer, _
                    ByVal BloodType As String, ByVal BirthDate As DateTime, ByVal BirthPlace As String)

        Me.Name = Name
        Me.Age = Age
        Me.m_BloodType = BloodType
        Me.m_BirthDate = BirthDate
        Me.m_BirthPlace = BirthPlace

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        Dim aibon As New ClassForSerialization("加護亜依", 15, "AB", New DateTime(1988, 2, 7), "奈良県")
        Dim serializer As New XmlSerializer(aibon.GetType)
        Dim writer As New StreamWriter("E:\Serialization_02.xml", False, Encoding.UTF8)

        serializer.Serialize(writer, aibon)

        writer.Close()

        Return 0

    End Function

End Module

<Serializable()> _
Public Class ClassForSerialization

    Public Name As String
    Public Age As Integer
    <XmlIgnore()> Public BloodType As String
    <XmlIgnore()> Public BirthDate As DateTime
    Public BirthPlace As String

    Public Sub New()
    End Sub

    Public Sub New(ByVal Name As String, ByVal Age As Integer, _
                    ByVal BloodType As String, ByVal BirthDate As DateTime, ByVal BirthPlace As String)

        Me.Name = Name
        Me.Age = Age
        Me.BloodType = BloodType
        Me.BirthDate = BirthDate
        Me.BirthPlace = BirthPlace

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        Dim aibon As New ClassForSerialization("加護亜依", 15, "AB", New DateTime(1988, 2, 7), "奈良県")
        Dim serializer As New XmlSerializer(aibon.GetType)
        Dim writer As New StreamWriter("E:\Serialization_03.xml", False, Encoding.UTF8)

        serializer.Serialize(writer, aibon)

        writer.Close()

        Return 0

    End Function

End Module

<Serializable()> _
Public Class ClassForSerialization

    <XmlElement("氏名")> Public Name As String
    <XmlElement("年齢")> Public Age As Integer
    <XmlElement("血液型")> Public BloodType As String
    <XmlElement("誕生日")> Public BirthDate As DateTime
    <XmlElement("出生地")> Public BirthPlace As String

    Public Sub New()
    End Sub

    Public Sub New(ByVal Name As String, ByVal Age As Integer, _
                    ByVal BloodType As String, ByVal BirthDate As DateTime, ByVal BirthPlace As String)

        Me.Name = Name
        Me.Age = Age
        Me.BloodType = BloodType
        Me.BirthDate = BirthDate
        Me.BirthPlace = BirthPlace

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        ' インスタンスを作成
        Dim aibon As New Musume("加護亜依", New DateTime(1988, 2, 7))
        Dim konkon As New Musume("紺野あさ美", New DateTime(1987, 5, 7))
        Dim nacchi As New Musume("安部なつみ", New DateTime(1981, 8, 10))

        ' インスタンスから配列を作成する
        Dim members() As Musume = {aibon, konkon, nacchi}

        ' 配列を内包するクラスを作成
        Dim musume As New MorningMusume()
        musume.Members = members

        ' シリアル化
        Dim serializer As New XmlSerializer(musume.GetType())
        Dim writer As New StreamWriter("E:\Serialization_04.xml", False, Encoding.UTF8)

        serializer.Serialize(writer, musume)

        writer.Close()

        Return 0

    End Function

End Module

' MorningMusumeクラス
<Serializable()> _
Public Class MorningMusume

    <XmlArrayItem(GetType(Musume))> _
    Public Members As Musume()

    Public Sub New()
    End Sub

End Class

' Musumeクラス
Public Class Musume

    Public Name As String
    Public Age As Integer
    Public BirthDate As DateTime

    Public Sub New()
    End Sub

    Public Sub New(ByVal Name As String, ByVal BirthDate As DateTime)

        Me.Name = Name
        Me.BirthDate = BirthDate

        ' 年齢って誕生日から計算できますね・・・
        Me.Age = DateTime.Now.Year - BirthDate.Year

        Dim birthDayInThisYear As New DateTime(DateTime.Now.Year, BirthDate.Month, BirthDate.Day)

        If birthDayInThisYear > DateTime.Now Then Me.Age -= 1

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        Dim aibon As New Musume("加護亜依", New DateTime(1988, 2, 7), 4)
        Dim konkon As New Musume("紺野あさ美", New DateTime(1987, 5, 7), 5)
        Dim nacchi As New Musume("安部なつみ", New DateTime(1981, 8, 10), 1)
        Dim mikitty As New Girl("藤本美貴", New DateTime(1985, 2, 26))
        Dim ayaya As New Girl("松浦亜弥", New DateTime(1986, 6, 25))

        Dim members() As Girl = {aibon, konkon, nacchi, mikitty, ayaya}

        Dim hello As New HelloProject()
        hello.Members = members

        Dim serializer As New XmlSerializer(hello.GetType())
        Dim writer As New StreamWriter("E:\Serialization_05.xml", False, Encoding.UTF8)

        serializer.Serialize(writer, hello)

        writer.Close()

        Return 0

    End Function

End Module

' HelloProjectクラス
<Serializable()> _
Public Class HelloProject

    <XmlArrayItem(GetType(Girl)), _
     XmlArrayItem(GetType(Musume))> _
    Public Members As Girl()

    Public Sub New()
    End Sub

End Class

' Girlクラス
Public Class Girl

    Public Name As String
    Public Age As Integer
    Public BirthDate As DateTime

    Public Sub New()
    End Sub

    Public Sub New(ByVal Name As String, ByVal BirthDate As DateTime)

        Me.Name = Name
        Me.BirthDate = BirthDate

        Me.Age = DateTime.Now.Year - BirthDate.Year

        Dim birthDayInThisYear As New DateTime(DateTime.Now.Year, BirthDate.Month, BirthDate.Day)

        If birthDayInThisYear > DateTime.Now Then Me.Age -= 1

    End Sub

End Class

' Musumeクラス
Public Class Musume
    Inherits Girl

    Public Generation As Integer

    Public Sub New()
    End Sub

    Public Sub New(ByVal Name As String, ByVal BirthDate As DateTime, ByVal Generation As Integer)

        MyBase.New(Name, BirthDate)
        Me.Generation = Generation

    End Sub

End Class

Imports System
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Text

Module Module1

    Public Function Main(ByVal args() As String) As Integer

        Dim hello As New HelloProject()
        Dim serializer As New XmlSerializer(hello.GetType())
        Dim reader As New StreamReader("E:\Serialization_05.xml")

        hello = serializer.Deserialize(reader)

        reader.Close()

        Dim girl As Girl

        For Each girl In hello.Members

            Console.Write("名前: {0} ({1}歳, 誕生日{2}) ", girl.Name, girl.Age, girl.BirthDate.ToLongDateString)

            If TypeOf girl Is Musume Then

                Console.WriteLine("第" + CType(girl, Musume).Generation.ToString() + "期メンバー")

            Else

                Console.Write(vbNewLine)

            End If

        Next

        Return 0

    End Function

End Module