Microsoft.VisualBasic.FileIO.TextFieldParser

Imports System
Imports System.Text
Imports Microsoft.VisualBasic.FileIO

Class TextFieldParserSample

  Public Shared Function Main() As Integer

    Dim parser As TextFieldParser = Nothing

    Try

      parser = New TextFieldParser( "sample.csv", Encoding.UTF8 )

      ' フィールドはデリミタにより区切られている(固定長の形式ではない)
      parser.TextFieldType = FieldType.Delimited

      ' 「#」で始まる行をコメントとして扱う
      parser.CommentTokens = New String() {"#"}

      ' 「,」をデリミタとして扱う
      parser.Delimiters = New String() {","}

      ' 引用符でくくられたフィールドを持つ
      parser.HasFieldsEnclosedInQuotes = True

      ' フィールドの前後に含まれる空白をトリムする
      parser.TrimWhiteSpace = True

      ' データがなくなるまで読み取り続ける
      Do Until parser.EndOfData

        Try

          ' 一行分のフィールドを読む
          Dim fields As String() = parser.ReadFields()

          Console.Write( "Line {0:D3} :", parser.LineNumber - 1 )

          For Each field As String In fields

            ' 読み取った各フィールドを大括弧でくくって表示する
            Console.Write( "[{0}] ", field )

          Next

          Console.WriteLine()

        Catch ex As MalformedLineException

          ' 読み込んでいる途中で指定したフォーマットに反するような行が見つかった場合
          Console.WriteLine( ex.Message )

          If parser IsNot Nothing Then

            ' 読み込めなかった行に関する情報を表示する
            Console.WriteLine( "Error at line {0}: {1}", parser.LineNumber, parser.ErrorLine )

          End If

        End Try

      Loop

    Finally

      If parser IsNot Nothing Then parser.Close()

    End Try

    Return 0

  End Function

End Class